#Include Once "windows.bi"
#Include "win/exdisp.bi"

Dim Shared IWebBrowser As IWebBrowser2Vtbl Ptr
Dim Shared As HWND hwndmain
Dim msg As MSG
Dim As WNDCLASSEX wc
Dim As String NameClass="MyClass"
Dim As HINSTANCE Hinst=GetModuleHandle(0)

Function WebGadget(ByVal Gadget As Integer,ByVal x As Integer,ByVal y As Integer,ByVal Width_ As Integer,ByVal Height_ As Integer,ByVal URL As String=" ",ByVal par1 As Integer=0,ByVal par2 As Integer=0) As Integer Ptr Export
  Dim i As Integer
  Dim pIWebBrowser As Integer Ptr
  Dim AtlAxWinInit As Function As Boolean
  Dim AtlAxGetControl As Function (ByVal hWin As HWND,ByRef pp As Integer Ptr) As Integer
  Dim pIUnknown As Integer Ptr
  Dim IUnknown As IUnknownVtbl Ptr
  Var hDll=LoadLibrary("atl.dll")
  If hDll Then
   AtlAxWinInit=Cast(Any Ptr,GetProcAddress(hDll,"AtlAxWinInit"))
   AtlAxGetControl=Cast(Any Ptr,GetProcAddress(hDll,"AtlAxGetControl"))
   If AtlAxWinInit() Then
    Var hWeb=CreateWindowEx(par2,"AtlAxWin",URL,WS_CHILD Or WS_VISIBLE Or par1,x,y,width_,height_,hwndMain,Cast(HMENU,gadget),0,0)
    AtlAxGetControl(hWeb,pIUnknown)
    IUnknown=Cast(IUnknownVtbl Ptr,*pIUnknown)
    i=IUnknown->AddRef(Cast(IUnknown Ptr,pIUnknown))
    i=IUnknown->QueryInterface(Cast(IUnknown Ptr,pIUnknown),@IID_IWebBrowser2,@pIWebBrowser)
    IWebBrowser=Cast(IWebBrowser2Vtbl Ptr,*pIWebBrowser)
    i=IWebBrowser->AddRef(Cast(IWebBrowser2 Ptr,pIWebBrowser))
    i=IUnknown->Release(Cast(IUnknown Ptr,pIUnknown))
    Return pIWebBrowser
   EndIf
  EndIf
End Function

Function WebGadgetNavigate(ByVal pIWebBrowser As Integer Ptr,ByVal URL As WString Ptr) As Integer Export
   If *URL<>"" Then
     Return IWebBrowser->Navigate(Cast(IWebBrowser2 Ptr,pIWebBrowser),Cast(BSTR,URL),NULL,NULL,NULL,NULL)
   EndIf
End Function

Function wndproc(hwnd As HWND, msg As UInteger,_
  wparam As WPARAM, lparam As LPARAM) As Integer
  Select Case msg
   Case WM_DESTROY
    PostQuitMessage(0)
  End Select
  Return DefWindowProc(hwnd,msg,wparam,lparam)
End Function

With wc
.cbSize=SizeOf(WNDCLASSEX)
.style=CS_HREDRAW Or CS_VREDRAW
.lpfnWndProc=@wndproc
.hInstance=Hinst
.hIcon=LoadIcon(0,IDI_QUESTION)
.hCursor=LoadCursor(0,IDC_ARROW)
.hbrBackground=Cast(HBRUSH,COLOR_WINDOWFRAME)
.lpszClassName=StrPtr(NameClass)
.hIconSm=.hIcon
End With

If RegisterClassEx(@wc)=0 Then
  Print "Register error, press any key"
  Sleep
  End
EndIf

hwndmain = CreateWindowEx(0,NameClass,"",_
WS_VISIBLE Or WS_OVERLAPPEDWINDOW,100,100,500,350,0,0,Hinst,0)
WebGadget(1,10,10,480,300,"www.ya.ru")

While GetMessage(@msg,0,0,0)
  TranslateMessage(@msg)
  DispatchMessage(@msg)
Wend