for (i = 0; (i < (sizeof(clause_terminations) / sizeof(uint16_t))) && (clause_terminations [i]!= termination); i++)[/i]

#macro CFOR(startexpr,condexpr,stepexpr)
startexpr
while condexpr
#ifdef CNEXT
#undef CNEXT
#endif
#ifndef CNEXT
#macro CNEXT?()
stepexpr
wend
#endmacro
#endif
#endmacro

dim i as integer
CFOR(i=0,i<5,i+=1)
print "i=",i
cfor(dim j as integer =0,j<10,j+=1)
print "j=", j
CNEXT
CNEXT
/code]
Пример второй:

#macro CFOR(startexpr,condexpr,stepexpr)
startexpr
while condexpr
#ifndef CNEXT
#macro CNEXT?()
stepexpr
wend
#endmacro
#endif
#endmacro

dim i as integer
CFOR(i=0,i<5,i+=1)
print "i=",i
cfor(dim j as integer =0,j<10,j+=1)
print "j=", j
CNEXT
CNEXT

Первый код будет не рабочий, и вот что получается в развёрнутом виде при помощи ключа -pp:

dim i as integer
 i=0
while i<5
print "i=",i
 dim j as integer =0
while j<10
print "j=", j
 j+=1
wend
CNEXT

Последний макрос не развернулся, но оно и понятно, он отменен при помощи #undef.
Развёрнутый второй код рабочий но неправильно:

dim i as integer
 i=0
while i<5
print "i=",i
 dim j as integer =0
while j<10
print "j=", j
 i+=1
wend
 i+=1
wend

Type CycleCounter
   Declare Constructor( ByVal n As Integer )
   ' Переопределение для неявного использования
   Declare Operator For ( )
   Declare Operator Step( )
   Declare Operator Next( ByRef end_cond As CycleCounter ) As Integer
   
   ' Счётчик
   i As Integer
End Type

Dim Shared clause_terminations As ZString * 265 = "Hello world!"
Dim Shared termination As Integer = 0

For i As CycleCounter = 0 To 100
   If clause_terminations[i.i] = 32 Then
      ' Теперь можно делать Continue
      ' и счётчик не забудет обновлять сам себя
      Continue For
      ' это просто для примера
      ' чтобы не печатать символы с пробелом
   End If
   ' печатаем текущее значение счётчика и символ из строки
   ' для самоуспокоения
   Print i.i, clause_terminations[i.i]
Next

Constructor CycleCounter( ByVal n As Integer )
   ' Конструктор, просто инициализируемся
   i = n
End Constructor

Operator CycleCounter.For( )
   Print "implicit step"
End Operator

Operator CycleCounter.Step( )
   ' Эта функция будет вызываться для приращения счётчика
   ' по умолчанию приращиваем счётчик на единицу
   this.i += 1
End Operator

Operator CycleCounter.Next( ByRef end_cond As CycleCounter ) As Integer
   ' Эта функция вызывается для проверки окончания цикла
   
   ' Параметр end_cond — это то, что стоит в выражении To
   ' то есть мы должны сравнить себя с параметром end_cond
   ' но в этом примере мы игнорируем этот параметр
   
   ' Мы должны вернуть 1 если цикл ещё не завершён
   ' и 0 когда цикл завершён
   
   ' Тут немного изменённое условие
   ' Но можно взять любое другое условие
   If i < (SizeOf(clause_terminations) \ SizeOf(WString)) AndAlso clause_terminations [i]<> termination Then
      Return 1
   End If
   Return 0
End Operator[/i]

#include once "FileIterator.bi"
#include once "crt.bi"

Const FormatString = !"%s\r\n"

Function EntryPoint Alias "EntryPoint"() As Integer
   
   For fff As FileIteratorW = WStr("*") To WStr("")
      wprintf(@WStr(FormatString), @fff.FindData.cFileName)
   Next
   
   Return 0
   
End Function

#ifndef FILEITERATOR_BI
#define FILEITERATOR_BI

#include once "windows.bi"

Type FileIteratorW
   Declare Constructor(ByRef ListingDir As WString)
   Declare Destructor()
   Declare Operator For()
   Declare Operator Step()
   Declare Operator Next(ByRef endCond As FileIteratorW) As Integer
   
   FindData As WIN32_FIND_DATAW
   hFind As HANDLE
   pListingDir As WString Ptr
   resFindNext As BOOL
End Type

#endif

#include once "FileIterator.bi"

Constructor FileIteratorW(ByRef ListingDir As WString)
   hFind = INVALID_HANDLE_VALUE
   pListingDir = @ListingDir
   resFindNext = TRUE
End Constructor

Destructor FileIteratorW()
   If hFind <> INVALID_HANDLE_VALUE Then
      FindClose(hFind)
   End If
End Destructor

Operator FileIteratorW.For()
   hFind = FindFirstFileW( _
      pListingDir, _
      @FindData _
   )
End Operator

Operator FileIteratorW.Step()
   resFindNext = FindNextFileW( _
      hFind, _
      @FindData _
   )
End Operator

Operator FileIteratorW.Next(ByRef endCond As FileIteratorW) As Integer
   If hFind = INVALID_HANDLE_VALUE Then
      Return 0
   End If
   If resFindNext = 0 Then
      Return 0
   End If
   Return 1
End Operator