#include once "windows.bi"

Function LoadStringExW Alias "LoadStringExW"( _
      ByVal hInst As HINSTANCE, _
      ByVal uId As UINT, _
      ByVal lpBuffer As LPWSTR, _
      ByVal cchBufferMax As Long, _
      ByVal langId As UINT _
   ) As Long

   ' Convert the string ID into a bundle number
   Dim ResId As UInteger = CUInt(uId) \ 16 + 1
   Dim hRes As HRSRC = FindResourceEx( _
      hInst, _
      RT_STRING, _
      MAKEINTRESOURCE(ResId), _
      langId _
   )

   If hRes Then
      Dim hglob As HGLOBAL = LoadResource(hInst, hRes)

      If hglob Then

         Dim pData As Any Ptr = LockResource(hglob)

         If pData Then
            ' Now walk the string table

            Dim pwsz As LPWSTR = Cast(LPWSTR, pData)

            Dim pLength As UShort Ptr = Cast(UShort Ptr, pwsz)
            Dim Length As UShort = *pLength
            pwsz = @pwsz[1]

            Dim Index As Integer = CInt(uId) And 15
            For i As Integer = 1 To Index
               pwsz = @pwsz[CInt(Length)]

               pLength = Cast(UShort Ptr, pwsz)
               Length = *pLength

               pwsz = @pwsz[1]
            Next

            Dim LenMin As Integer = min(CInt(Length), CInt(cchBufferMax))

            If LenMin Then
               CopyMemory(lpBuffer, pwsz, LenMin * SizeOf(WCHAR))
            End If

            lpBuffer [LenMin]= 0

            Return LenMin
         End If
      End If
   End If

   lpBuffer[0] = 0

   Return 0

End Function

Function LoadStringExA Alias "LoadStringExA"( _
      ByVal hInst As HINSTANCE, _
      ByVal uId As UINT, _
      ByVal lpBuffer As LPSTR, _
      ByVal cchBufferMax As Long, _
      ByVal langId As UINT _
   ) As Long

   Dim pBuf As LPWSTR = Allocate((cchBufferMax + 1) * SizeOf(WCHAR))
   If pBuf = NULL Then
      lpBuffer[0] = 0
      Return 0
   End If

   Dim resLength As Long = LoadStringExW( _
      hInst, _
      uId, _
      pBuf, _
      cchBufferMax, _
      langId _
   )

   If resLength Then
      WideCharToMultiByte( _
         CP_ACP, _
         0, _
         pBuf, _
         resLength, _
         lpBuffer, _
         cchBufferMax, _
         NULL, _
         NULL _
      )
   End If

   Deallocate(pBuf)

   lpBuffer [resLength]= 0

   Return resLength

End Function

#ifndef LOADSTRINGEX_BI
#define LOADSTRINGEX_BI

#include once "windows.bi"

Declare Function LoadStringExW( _
   ByVal hInst As HINSTANCE, _
   ByVal uId As UINT, _
   ByVal lpBuffer As LPWSTR, _
   ByVal cchBufferMax As Long, _
   ByVal langId As UINT _
) As Long

Declare Function LoadStringExA( _
   ByVal hInst As HINSTANCE, _
   ByVal uId As UINT, _
   ByVal lpBuffer As LPSTR, _
   ByVal cchBufferMax As Long, _
   ByVal langId As UINT _
) As Long

#ifdef UNICODE
   Declare Function LoadStringEx Alias "LoadStringExW"( _
      ByVal hInst As HINSTANCE, _
      ByVal uId As UINT, _
      ByVal lpBuffer As LPWSTR, _
      ByVal cchBufferMax As Long, _
      ByVal langId As UINT _
   ) As Long
#else
   Declare Function LoadStringEx Alias "LoadStringExA"( _
      ByVal hInst As HINSTANCE, _
      ByVal uId As UINT, _
      ByVal lpBuffer As LPSTR, _
      ByVal cchBufferMax As Long, _
      ByVal langId As UINT _
   ) As Long
#endif

#endif

#include "resources.rh"

LANGUAGE LANG_ENGLISH, SUBLANG_DEFAULT

STRINGTABLE
BEGIN
   IDS_MESSAGE1             "Done"
   IDS_MESSAGE2             "Caption"
END

LANGUAGE LANG_RUSSIAN, SUBLANG_DEFAULT

STRINGTABLE
BEGIN
   IDS_MESSAGE1             "Готово"
   IDS_MESSAGE2             "Заголовок"
END

#define IDS_MESSAGE1 16
#define IDS_MESSAGE2 17

#include once "resources.rh"
#include once "LoadStringEx.bi"

' конструируем язык самостоятельно

Dim lngId As Long = MAKELANGID(LANG_ENGLISH, SUBLANG_DEFAULT)

Dim buf1(63) As TCHAR = Any
Dim StringLength1 As Long = LoadStringEx( _
    GetModuleHandle(NULL), _
    IDS_MESSAGE1, _
    @buf1(0), _
    63, _
    lngId _
)

Dim buf2(63) As TCHAR = Any
Dim StringLength2 As Long = LoadStringEx( _
    GetModuleHandle(NULL), _
    IDS_MESSAGE2, _
    @buf2(0), _
    63, _
    lngId _
)

MessageBox( _
    hWin, _
    @buf1(0), _
    @buf2(0), _
    MB_OK Or MB_ICONINFORMATION _
)