#Include "windows.bi"        

        Private Type Vector        
        x As Single        
        y As Single        
        End Type        

        Dim Shared bi32BitInfo As BITMAPINFO        
        Dim Shared Map(767, 1023) As Long        
        Declare Sub DrawFractal(vPos As Vector, vDir As Vector)        
        Declare Sub DrawLine(vP1 As Vector, vP2 As Vector)        
        Declare Sub Main()        
        Dim Shared QSpeed As Double        

        Main '<- вход        

        Private Function QTime() As Double        
         Dim QD As LARGE_INTEGER, t As Double        
         QueryPerformanceCounter @QD        
         If QD.LowPart < 0 Then t = QD.LowPart + 4294967296 Else t = QD.LowPart        
         If QD.HighPart < 0 Then t = t + (QD.HighPart + 4294967296) * 4294967296 Else t = t + QD.HighPart * 4294967296        
         QTime = t * QSpeed        
        End Function        

        Private Sub QTimeInit()        
         Dim QD As LARGE_INTEGER        
         QueryPerformanceFrequency @QD        
         If QD.LowPart < 0 Then QSpeed = QD.LowPart + 4294967296 Else QSpeed = QD.LowPart        
         If QD.HighPart < 0 Then QSpeed = QSpeed + (QD.HighPart + 4294967296) * 4294967296 Else QSpeed = QSpeed + QD.HighPart * 4294967296        
         QSpeed = 1 / QSpeed        
        End Sub        

        Private Sub Main()        
         Dim vP As Vector, vD As Vector        
         Dim t1 As Single, t2 As Single        
         Dim msg As MSG        

         QTimeInit        
         vP.x = 40        
         vP.y = 500        
         vD.x = 87        
         vD.y = -54        

         t1 = QTime        
         DrawFractal vP, vD        
         t2 = QTime        

         With bi32BitInfo.bmiHeader        
          .biBitCount = 32        
          .biPlanes = 1        
          .biSize = Len(bi32BitInfo.bmiHeader)        
          .biWidth = 1024        
          .biHeight = -768        
          .biSizeImage = 4 * 1024 * 768        
         End With        
         Var hwnd=CreateWindowEx(0,"#32770","",WS_VISIBLE Or WS_OVERLAPPEDWINDOW,10,10,1024,768,0,0,0,0)        
         Dim wRect As RECT        
         GetWindowRect(hWnd,@wRect)        
         wRect.right   = wRect.right-wRect.left        
         wRect.bottom  = wRect.bottom-wRect.top        
         MoveWindow(hWnd,(GetSystemMetrics(0) Shr 1) - (wRect.right Shr 1),_        
         (GetSystemMetrics(1) Shr 1) - (wRect.bottom Shr 1),_        
         wRect.right, wRect.bottom, 1)        
         Var hdc = GetDC(hwnd)        
         SetDIBitsToDevice( hdc, 0, 0, 1024, 768, 0, 0, 0, 768, @Map(0, 0), @bi32BitInfo, 0)        
         SetBkColor(hDC,&h0)        
         SetTextColor(hDC,&hffffff)        
         TextOut(hdc,20,20,Str(t2-t1),Len(Str(t2-t1)))        
         DeleteDC(hdc)        
         While GetMessage(@msg,0,0,0)        
          DispatchMessage(@msg)        
          If msg.message=WM_COMMAND Then Exit While        
         Wend        
        End Sub        

        Private Sub DrawFractal(vPos As Vector, vDir As Vector)        
         Dim vP As Vector, vD As Vector        

         If vDir.x * vDir.x + vDir.y * vDir.y < 0.017 Then Exit Sub        
         vP.x = vPos.x + vDir.x        
         vP.y = vPos.y + vDir.y        
         DrawLine vPos, vP        

         vD.x = vDir.x * 0.9 - vDir.y * 0.04        
         vD.y = vDir.y * 0.9 + vDir.x * 0.04        
         DrawFractal vP, vD        
         vD.x = vDir.x * 0.15 + vDir.y * 0.24        
         vD.y = vDir.y * 0.15 - vDir.x * 0.24        
         DrawFractal vP, vD        
         vD.x = vDir.x * 0.14 - vDir.y * 0.25        
         vD.y = vDir.y * 0.14 + vDir.x * 0.25        
         DrawFractal vP, vD        
        End Sub        

        Private Sub DrawLine(vP1 As Vector, vP2 As Vector)        
         Dim x As Single, y As Single, k As Single, dx As Single, dy As Single        

         dx = vP2.x - vP1.x        
         dy = vP2.y - vP1.y        
         If Abs(dx) < Abs(dy) Then        
          k = dx / dy        
          If vP2.y > vP1.y Then        
           y = vP1.y        
           x = vP1.x        
           While y < vP2.y        
            Map(y, x) = &H50BB50        
            x = x + k        
            y = y + 1        
           Wend        
          Else        
           y = vP2.y        
           x = vP1.x        
           While y < vP1.y        
            Map(y, x) = &H40FF30        
            x = x + k        
            y = y + 1        
           Wend        
          End If        
         Else        
          k = dy / dx        
          If vP2.x > vP1.x Then        
           x = vP1.x        
           y = vP1.y        
           While x < vP2.x        
            Map(y, x) = &HA0AF20        
            y = y + k        
            x = x + 1        
           Wend        
          Else        
           x = vP2.x        
           y = vP1.y        
           While x < vP1.x        
            Map(y, x) = &H609F30        
            y = y + k        
            x = x + 1        
           Wend        
          End If        
         End If        
        End Sub