#INCLUDE ONCE "windows.bi"

#IFNDEF RB_GETBANDBORDERS
CONST RB_GETBANDBORDERS = 1058
#ENDIF

DIM hTray AS HWND = FindWindowEx (0, 0, @"Shell_TrayWnd", 0)
DIM hReBar AS HWND = FindWindowEx (hTray, 0, @"ReBarWindow32", 0)
'DIM hQuickLaunch AS HWND = FindWindowEx(hReBar, 0, @"ToolbarWindow32", 0)

DIM Razm AS RECT

SendMessage(hReBar, RB_GETBANDBORDERS, 0, VARPTR(Razm))

SLEEP 100, 1

PRINT Razm.Top
PRINT Razm.Left
PRINT Razm.Right
PRINT Razm.Bottom

SLEEP

DIM rbbi AS REBARBANDINFO
   ZeroMemory(@rbbi, SIZEOF(REBARBANDINFO))

   rbbi.cbSize = SIZEOF(REBARBANDINFO)
   rbbi.fMask = RBBIM_SIZE    '   Гугл "помощник" выдал RBBIM_CX, но такой константы не нашёл, в хедере есть только RBBIM_SIZE
   rbbi.cx = 400

   SendMessage(hReBar, RB_SETBANDINFO, 0, @rbbi)

Ты [url=https://users.freebasic-portal.de/freebasicru/hackgame.html]эту[/url] имеешь ввиду?

ShowWindow (hReBar, SW_HIDE OR AW_HOR_NEGATIVE)
ShowWindow (hReBar, SW_SHOWNA OR AW_HOR_NEGATIVE)

'
' [ AUTO_QL.BAS ] - Динамический размер панели быстрого запуска
' Версия:  0.5 \ Альфа
' FBC   :  1.10.1 (64 Бит)
'

  '$Lang: "FB"

#INCLUDE ONCE "windows.bi"
#INCLUDE ONCE "Win\tlhelp32.bi"

  DECLARE SUB  InitALL ()
  DECLARE SUB  RefreshQuickLaunch ()
  DECLARE SUB  GetIconCount ()

  DECLARE FUNCTION  ExamineFolder (BYVAL DirectoryName AS STRING, BYVAL Pattern AS STRING) AS INTEGER
  DECLARE FUNCTION  GetNextEntry  (BYVAL DirHandle AS INTEGER) AS INTEGER
  DECLARE FUNCTION  FinishSearch  (BYVAL DirHandle AS INTEGER) AS INTEGER
  DECLARE FUNCTION  GetAttributes () AS INTEGER
  DECLARE FUNCTION  DirEntryName  () AS STRING

DIM SHARED  FileInfo AS WIN32_FIND_DATA

DIM SHARED  hTray AS HWND
DIM SHARED  hReBar AS HWND
DIM SHARED  hQuickLaunch AS HWND

DIM SHARED  BarWidthAdress AS INTEGER = &H0041A360
DIM SHARED  Icons AS INTEGER
DIM SHARED  LastCount AS INTEGER
DIM SHARED  Pixels AS LONG         '  4 байта - ширина меню быстрого запуска

DIM SHARED  Path AS STRING         '  Путь к папке быстрого запуска

DIM SHARED ShotID AS HANDLE        '  Хендл снимка процессов
DIM SHARED Exp_ID AS DWORD         '  Найденный ID процесса explorer.exe
DIM SHARED PID_RW AS HANDLE        '  Открытый дескриптор процесса
DIM SHARED FoundExp AS INTEGER     '  Найден ли Program Manager (explorer.exe)
DIM SHARED WrkAddr AS LPVOID       '  Адрес куда пишем данные
DIM SHARED BytesDo AS ULONGINT     '  Сколько байт было записано
DIM SHARED FResult AS INTEGER

'  Делаем снимок процессов
ShotID = CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0)
IF ShotID <> INVALID_HANDLE_VALUE THEN
  DIM pe32 AS PROCESSENTRY32
  pe32.dwSize = SIZEOF(PROCESSENTRY32)
    Process32First (ShotID, VARPTR(pe32))
    IF Process32First (ShotID, VARPTR(pe32)) THEN
      DO

        IF pe32.szExeFile = "explorer.exe" THEN        ' explorer.exe
          SLEEP 100, 1
          FoundExp = -1
          Exp_ID = pe32.th32ProcessID
          EXIT DO
        END IF

      LOOP WHILE Process32Next(ShotID, VARPTR(pe32))
    END IF
END IF

InitALL ()
GetIconCount ()          '  Узнаем кол-во иконок на старте
LastCount = Icons        '  Запомним кол-во иконок

PRINT "FoundExp ="; FoundExp

DO
   SLEEP 1000, 1
   GetIconCount ()        '  Узнаем кол-во иконок
  
   '  Если изменилось
   IF Icons <> LastCount THEN
      PRINT "Izmen...ok"
      IF FoundExp THEN
        PID_RW = OpenProcess(PROCESS_VM_READ OR PROCESS_VM_WRITE OR PROCESS_VM_OPERATION, 0, Exp_ID)
        IF PID_RW <> 0 THEN
         '  Пишем в память ширину
           WrkAddr = CAST(LPVOID, BarWidthAdress)
           FResult = WriteProcessMemory(PID_RW, WrkAddr, @Pixels, SIZEOF(Pixels), @BytesDo)
           'FResult = ReadProcessMemory(PID_RW, WrkAddr, @Pixels, SIZEOF(Pixels), @BytesDo)
           PRINT "Pixels ="; Pixels
          CloseHandle(PID_RW)
        END IF
      END IF
      '  Если запись в память прошла успешно
      IF (FResult <> 0) AND BytesDo = 4 THEN
        
        RefreshQuickLaunch ()  '  Обновим быстрый запуск
        
        LastCount = Icons
        PRINT "Refresh...ok"
      END IF
   END IF

LOOP UNTIL INKEY = CHR(27)

END

'
'   Базовая инициализация
'
SUB InitALL ()
    hTray = FindWindowEx (0, 0, @"Shell_TrayWnd", 0)
    hReBar  = FindWindowEx (hTray, 0, @"ReBarWindow32", 0)
    hQuickLaunch = FindWindowEx(hReBar, 0, @"ToolbarWindow32", 0)
    Path = ENVIRON("userprofile") + "\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch"
END SUB

'
'   Обновление быстрого запуска
'
SUB RefreshQuickLaunch ()
    ShowWindow (hReBar, SW_HIDE OR AW_HOR_NEGATIVE)
    ShowWindow (hReBar, SW_SHOWNA OR AW_HOR_NEGATIVE)
END SUB

'
'   Узнать кол-во иконок (файлов в папке быстрого запуска)
'
SUB GetIconCount ()
    DIM fd AS WIN32_FIND_DATA
    DIM FId AS INTEGER
    DIM IsEntry AS INTEGER
    DIM TekFNm AS STRING      '  Текущее имя файла\директории
    DIM DEA AS INTEGER        '  DirectoryEntryAttributes

    FId = ExamineFolder(Path + "\", "*.*")

    Icons = 0
    IF FId THEN
      TekFNm = DirEntryName()
      DEA = GetAttributes()
      IF (DEA AND FILE_ATTRIBUTE_DIRECTORY) = 0 THEN
        IF LCASE(TekFNm) <> "desktop.ini" AND TekFNm <> "." AND TekFNm <> ".." THEN
          Icons += 1
        END IF
      END IF

      DO
        '  Есть ли на этом уровне файлы\папки
        IsEntry = GetNextEntry(FId)
        TekFNm = DirEntryName()
        DEA = GetAttributes()
        
        IF (IsEntry = 1) AND ((DEA AND FILE_ATTRIBUTE_DIRECTORY) = 0) THEN
          IF LCASE(TekFNm) <> "desktop.ini" AND TekFNm <> "." AND TekFNm <> ".." THEN
            Icons += 1
            'PRINT !"\u" + TekFNm + STR(IsEntry)
          END IF
        END IF
        'IF INKEY = CHR(27) THEN EXIT DO
      LOOP UNTIL IsEntry = 0
    
      FinishSearch(FId)
    END IF
    
    '  Вычисляем по кол-ву пикселей на иконку правую границу
    Pixels = Icons * 23 + 4
    
END SUB

   '    Обёртка из WinAPI для сканирования директории

FUNCTION ExamineFolder(BYVAL DirectoryName AS STRING, BYVAL Pattern AS STRING) AS INTEGER
   DIM strPattern AS STRING
   strPattern = DirectoryName + Pattern + CHR(0)
   RETURN CINT(FindFirstFile(SADD(strPattern), @FileInfo))
END FUNCTION

FUNCTION GetNextEntry(BYVAL DirHandle AS INTEGER) AS INTEGER
   RETURN FindNextFile(CAST(HANDLE, DirHandle), @FileInfo)
END FUNCTION

FUNCTION FinishSearch(BYVAL DirHandle AS INTEGER) AS INTEGER
   RETURN FindClose(CAST(HANDLE, DirHandle))
END FUNCTION

FUNCTION GetAttributes() AS INTEGER
   RETURN FileInfo.dwFileAttributes
END FUNCTION

FUNCTION DirEntryName() AS STRING
   RETURN FileInfo.cFileName
END FUNCTION